git のコミットメッセージにおけるコメント開始文字を # から ; に変更する


はじめに

先日、git のコミットメッセージ内に # から始まる行(やむなくルートシェルで実行したコマンドをメモしておきたかった・・・)を入れてしまい、コミットメッセージからその部分が消し飛ぶと言う失態をやらかしました。うっかりさん。

まぁ自分が悪いのですが、これに限らず # から始まる行を書きたいこと(例えば Markdown っぽく書きたいとか?)もあるだろうと思い調べたところ、git の config をいじることでコメント開始文字を変更できる様なのでやってみました。ついでに、コミットメッセージを編集する際の neovim の設定もいじっていますのでお付き合いください。

commentChar の変更

git の設定変更自体は簡単で、.gitconfig に以下を追加するだけです。

~/.gitconfig
[core]
    commentChar = ";"

開始文字を何にしたら良いか?については、(また同じような失態をやらかしたく無いので)少し考えましたが、まぁ ; で良い気がします。セミコロンがコメントなんて、なんか懐かしい感じがしますね。

この状態で git commit すると、以下の様な感じでエディタが開きます。ちゃんとコメントが ; 始まりになっていますね。ちょっと新鮮ですが、すぐ慣れそうです。

gitcommit

; Please enter the commit message for your changes. Lines starting
; with ';' will be ignored, and an empty message aborts the commit.
;
; On branch gitcommit
; Your branch is up to date with 'origin/gitcommit'.
;
; Changes to be committed:
;	modified:   *******
;

neovim の設定変更

さて、# 始まりのコミットメッセージが書ける様になったのは良いのですが、コミットメッセージを編集する際に立ち上がる neovim のハイライト設定が # をコメントとして扱ったままですし、逆に ; はコメントとして扱ってくれません。気にしなければ気にしないで良いのかもしれませんが、どうにも気になるのでこっちも変更してみます。

2022-04-03 追記

当初は、自前で syntax ファイルを上書きして対応していたのですが、@4513echo さんからコメントでちょうど良いランタイムファイルを教えてきただきましたので、そちらでの設定をメインにしています。ありがとうございます。自前でミニマム対応したい方は、少し下へスクロールください。

tpope/git-vim の導入

教えていただいたランタイムファイル一式は ↓ のものです。よくみると、本家の gitcommit.vim を書いた方と同じ方の様です。神。ざっと中身も読んでみましたが、期待通り動きそうです。

https://github.com/tpope/vim-git

私の場合は、プラグインマネージャに dein.vim を利用しているので、dein.toml ファイルに以下の様に追加しました。あっという間。内容的には、git からファイル一式持ってきて、runtimepath に置けば動くと思います。

dein.toml
[[plugins]]
repo = 'tpope/vim-git'

コメント開始文字を見つけてくる行は、こんな ↓ 感じになっている様なので、#; だけでなく #;@!$%^&|: に対応していそうです。かしこし。

let s:comment = escape((matchstr(getline(s:l), '^[#;@!$%^&|:]\S\@!') . '#')[0], '^$.*[]~\"/')

gitcommit.vim の変更

neovim でコミットメッセージを編集する際の filetypegitcommit になっていますので、ハイライト設定は runtimepath 内の syntax/gitcommit.vim に記述すれば適用されます。neovim のインストールされているディレクトリから、デフォルトのファイルをまるまる拝借してきて改変することにします。

~/.config/nvim/syntax/gitcommit.vim
" Vim syntax file
" Language:	git commit file
" Maintainer:	Tim Pope <[email protected]>
" Filenames:	*.git/COMMIT_EDITMSG
" Last Change:	2019 Dec 05

if exists("b:current_syntax")
  finish
endif

syn case match
syn sync minlines=50

if has("spell")
  syn spell toplevel
endif

syn include @gitcommitDiff syntax/diff.vim
syn region gitcommitDiff start=/\%(^diff --\%(git\|cc\|combined\) \)\@=/ end=/^\%(diff --\|$\|;\)\@=/ fold contains=@gitcommitDiff

syn match   gitcommitSummary	"^.*\%<51v." contained containedin=gitcommitFirstLine nextgroup=gitcommitOverflow contains=@Spell
syn match   gitcommitOverflow	".*" contained contains=@Spell
syn match   gitcommitBlank	"^[^;].*" contained contains=@Spell

if get(g:, "gitcommit_cleanup") is# "scissors"
  syn match gitcommitFirstLine	"\%^.*" nextgroup=gitcommitBlank skipnl
  syn region gitcommitComment start=/^; -\+ >8 -\+$/ end=/\%$/ contains=gitcommitDiff
else
  syn match gitcommitFirstLine	"\%^[^;].*" nextgroup=gitcommitBlank skipnl
  syn match gitcommitComment	"^;.*"
endif

syn match   gitcommitHead	"^\%(;   .*\n\)\+;$" contained transparent
syn match   gitcommitOnBranch	"\%(^; \)\@<=On branch" contained containedin=gitcommitComment nextgroup=gitcommitBranch skipwhite
syn match   gitcommitOnBranch	"\%(^; \)\@<=Your branch .\{-\} '" contained containedin=gitcommitComment nextgroup=gitcommitBranch skipwhite
syn match   gitcommitBranch	"[^ ']\+" contained
syn match   gitcommitNoBranch	"\%(^; \)\@<=Not currently on any branch." contained containedin=gitcommitComment
syn match   gitcommitHeader	"\%(^; \)\@<=.*:$"	contained containedin=gitcommitComment
syn region  gitcommitAuthor	matchgroup=gitCommitHeader start=/\%(^; \)\@<=\%(Author\|Committer\):/ end=/$/ keepend oneline contained containedin=gitcommitComment transparent
syn match   gitcommitNoChanges	"\%(^; \)\@<=No changes$" contained containedin=gitcommitComment

syn region  gitcommitUntracked	start=/^; Untracked files:/ end=/^;$\|^;\@!/ contains=gitcommitHeader,gitcommitHead,gitcommitUntrackedFile fold
syn match   gitcommitUntrackedFile  "\t\@<=.*"	contained

syn region  gitcommitDiscarded	start=/^; Change\%(s not staged for commit\|d but not updated\):/ end=/^;$\|^;\@!/ contains=gitcommitHeader,gitcommitHead,gitcommitDiscardedType fold
syn region  gitcommitSelected	start=/^; Changes to be committed:/ end=/^;$\|^;\@!/ contains=gitcommitHeader,gitcommitHead,gitcommitSelectedType fold
syn region  gitcommitUnmerged	start=/^; Unmerged paths:/ end=/^;$\|^;\@!/ contains=gitcommitHeader,gitcommitHead,gitcommitUnmergedType fold


syn match   gitcommitDiscardedType	"\t\@<=[[:lower:]][^:]*[[:lower:]]: "he=e-2	contained containedin=gitcommitComment nextgroup=gitcommitDiscardedFile skipwhite
syn match   gitcommitSelectedType	"\t\@<=[[:lower:]][^:]*[[:lower:]]: "he=e-2	contained containedin=gitcommitComment nextgroup=gitcommitSelectedFile skipwhite
syn match   gitcommitUnmergedType	"\t\@<=[[:lower:]][^:]*[[:lower:]]: "he=e-2	contained containedin=gitcommitComment nextgroup=gitcommitUnmergedFile skipwhite
syn match   gitcommitDiscardedFile	".\{-\}\%($\| -> \)\@=" contained nextgroup=gitcommitDiscardedArrow
syn match   gitcommitSelectedFile	".\{-\}\%($\| -> \)\@=" contained nextgroup=gitcommitSelectedArrow
syn match   gitcommitUnmergedFile	".\{-\}\%($\| -> \)\@=" contained nextgroup=gitcommitSelectedArrow
syn match   gitcommitDiscardedArrow	" -> " contained nextgroup=gitcommitDiscardedFile
syn match   gitcommitSelectedArrow	" -> " contained nextgroup=gitcommitSelectedFile
syn match   gitcommitUnmergedArrow	" -> " contained nextgroup=gitcommitSelectedFile

syn match   gitcommitWarning		"\%^[^;].*: needs merge$" nextgroup=gitcommitWarning skipnl
syn match   gitcommitWarning		"^[^;].*: needs merge$" nextgroup=gitcommitWarning skipnl contained
syn match   gitcommitWarning		"^\%(no changes added to commit\|nothing \%(added \)\=to commit\)\>.*\%$"

hi def link gitcommitSummary		Keyword
hi def link gitcommitComment		Comment
hi def link gitcommitUntracked		gitcommitComment
hi def link gitcommitDiscarded		gitcommitComment
hi def link gitcommitSelected		gitcommitComment
hi def link gitcommitUnmerged		gitcommitComment
hi def link gitcommitOnBranch		Comment
hi def link gitcommitBranch		Special
hi def link gitcommitNoBranch		gitCommitBranch
hi def link gitcommitDiscardedType	gitcommitType
hi def link gitcommitSelectedType	gitcommitType
hi def link gitcommitUnmergedType	gitcommitType
hi def link gitcommitType		Type
hi def link gitcommitNoChanges		gitcommitHeader
hi def link gitcommitHeader		PreProc
hi def link gitcommitUntrackedFile	gitcommitFile
hi def link gitcommitDiscardedFile	gitcommitFile
hi def link gitcommitSelectedFile	gitcommitFile
hi def link gitcommitUnmergedFile	gitcommitFile
hi def link gitcommitFile		Constant
hi def link gitcommitDiscardedArrow	gitcommitArrow
hi def link gitcommitSelectedArrow	gitcommitArrow
hi def link gitcommitUnmergedArrow	gitcommitArrow
hi def link gitcommitArrow		gitcommitComment
"hi def link gitcommitOverflow		Error
hi def link gitcommitBlank		Error

let b:current_syntax = "gitcommit"

こんな感じで、「行頭の #(正規表現だと /^#/ とか)」や「行頭の # 以外(正規表現だと /^[^#]/ とか)」を指していると思われる部分を、ざざっと ; に置き換えています。このファイルを、自分のホーム配下の ~/.config/nvim/syntax/gitcommit.vim に配置すれば、こちらが優先して適用される様になります。vim のこういうところ良いよね。

おわりに

neovim でのハイライトも綺麗にされる様になり、これでストレスなくコミットメッセージを打てる様になりました。めでたしめでたし。