#include <M5Atom.h>
#include <WiFi.h>
#include <HTTPClient.h>

// Wi-Fi SSID
const char *ssid = "********";
// Wi-Fi Password
const char *password = "********";
// ボタン押下時の送信先
const char *endpoint_short = "http://********/api/v1/light/off";
// 長押し時の送信先
const char *endpoint_long = "http://********/api/v1/light/on";

// 長押し判定時間[ミリ秒]
const int32_t long_press_timeout = 1000;
// HTTP タイムアウト時間[ミリ秒]
const int32_t http_timeout = 10 * 1000;

const int32_t red = 0x004000;
const int32_t green = 0x300000;
const int32_t blue = 0x000040;
const int32_t white = 0x202020;

void setup()
{
  M5.begin(true, false, true);
  delay(10);
  M5.dis.setBrightness(10);
  M5.dis.drawpix(0, red);

  Serial.begin(115200);
  while (!Serial);
  delay(100);
  Serial.println("\nSerial started");

  connectWiFi();
  M5.dis.drawpix(0, green);
}

void connectWiFi()
{
  WiFi.disconnect(); // reset
  Serial.printf("Attempting to connect to SSID: %s\n", ssid);
  Serial.print("Connecting Wi-Fi");
  for (int i = 0; WiFi.status() != WL_CONNECTED; i++)
  {
    if (i % 10 == 0) {
      WiFi.begin(ssid, password);
    }
    Serial.print(".");
    delay(1000); // wait a second for connection
  }
  Serial.println("Connected");
}

void loop()
{
  if (WiFi.status() != WL_CONNECTED)
  {
    M5.dis.drawpix(0, red);
    connectWiFi();
    M5.dis.drawpix(0, green);
  }

  if (M5.Btn.wasPressed())
  {
    M5.dis.drawpix(0, blue);

    int32_t timeout = millis() + long_press_timeout;
    while (M5.Btn.isPressed() && millis() <= timeout)
    {
      delay(100);
      M5.Btn.read();
    }

    if (millis() <= timeout)
    {
      send(endpoint_short);
    }
    else
    {
      send(endpoint_long);
    }
  }

  delay(100);
  M5.update();
}

void send(String url)
{
  Serial.println("Start HTTP request");
  M5.dis.drawpix(0, white);

  HTTPClient http;
  http.begin(url);
  http.setReuse(false);
  http.setConnectTimeout(http_timeout);
  http.setTimeout(http_timeout);
  int status_code = http.POST("");
  Serial.printf("status_code=%d\r\n", status_code);
  Serial.println(HTTPClient::errorToString(status_code));
  if (status_code != 200)
  {
    Serial.println("request failed");
    M5.dis.drawpix(0, red);
  }
  http.end();

  delay(2000);
  M5.dis.drawpix(0, green);
}