Ethereum入門 〜独自トークンの発行〜


はじめに

Ethereum上で独自のトークンを発行してみます。

Gethのインストール

Gethのインストールから起動、マイニングまではこちらを参照ください。
Ethereum入門 〜GethインストールからETH送金まで〜

RPC設定しGethを起動

rpcオプションを設定することでbrowser-solidityからローカルネットワークへの接続することが出来るようになります。

$ geth --networkid 10 --nodiscover --maxpeers 0 --datadir ~/eth_testnet/ --rpc -rpccorsdomain "*" --rpcaddr "0.0.0.0"  console 2>> ~/eth_testnet/geth.log

browser-solidityの設定

browser-solidityのインストール

githubからbrowser-solidityをinstallします

$ git clone https://github.com/ethereum/browser-solidity.git

インストール後、browser-solidity内のindex.htmlを開くと、browser-solidityが開きます。
EnvironmentでWeb3 Providerを選択し、ポート番号はgethの8545を指定します。

接続されたらaccountを見てみます。
プライベートネットで作ったアカウントと残高が一致していることが確認出来ます。

独自トークンの発行

公式ページからサンプルコードをコピーします。

Create your own CRYPTO-CURRENCY with Ethereum

pragma solidity ^0.4.16;

interface tokenRecipient { function receiveApproval(address _from, uint256 _value, address _token, bytes _extraData) public; }

contract TokenERC20 {
    // Public variables of the token
    string public name;
    string public symbol;
    uint8 public decimals = 18;
    // 18 decimals is the strongly suggested default, avoid changing it
    uint256 public totalSupply;

    // This creates an array with all balances
    mapping (address => uint256) public balanceOf;
    mapping (address => mapping (address => uint256)) public allowance;

    // This generates a public event on the blockchain that will notify clients
    event Transfer(address indexed from, address indexed to, uint256 value);

    // This notifies clients about the amount burnt
    event Burn(address indexed from, uint256 value);

    /**
     * Constrctor function
     *
     * Initializes contract with initial supply tokens to the creator of the contract
     */
    function TokenERC20(
        uint256 initialSupply,
        string tokenName,
        string tokenSymbol
    ) public {
        totalSupply = initialSupply * 10 ** uint256(decimals);  // Update total supply with the decimal amount
        balanceOf[msg.sender] = totalSupply;                // Give the creator all initial tokens
        name = tokenName;                                   // Set the name for display purposes
        symbol = tokenSymbol;                               // Set the symbol for display purposes
    }

    /**
     * Internal transfer, only can be called by this contract
     */
    function _transfer(address _from, address _to, uint _value) internal {
        // Prevent transfer to 0x0 address. Use burn() instead
        require(_to != 0x0);
        // Check if the sender has enough
        require(balanceOf[_from] >= _value);
        // Check for overflows
        require(balanceOf[_to] + _value > balanceOf[_to]);
        // Save this for an assertion in the future
        uint previousBalances = balanceOf[_from] + balanceOf[_to];
        // Subtract from the sender
        balanceOf[_from] -= _value;
        // Add the same to the recipient
        balanceOf[_to] += _value;
        Transfer(_from, _to, _value);
        // Asserts are used to use static analysis to find bugs in your code. They should never fail
        assert(balanceOf[_from] + balanceOf[_to] == previousBalances);
    }

    /**
     * Transfer tokens
     *
     * Send `_value` tokens to `_to` from your account
     *
     * @param _to The address of the recipient
     * @param _value the amount to send
     */
    function transfer(address _to, uint256 _value) public {
        _transfer(msg.sender, _to, _value);
    }

    /**
     * Transfer tokens from other address
     *
     * Send `_value` tokens to `_to` on behalf of `_from`
     *
     * @param _from The address of the sender
     * @param _to The address of the recipient
     * @param _value the amount to send
     */
    function transferFrom(address _from, address _to, uint256 _value) public returns (bool success) {
        require(_value <= allowance[_from][msg.sender]);     // Check allowance
        allowance[_from][msg.sender] -= _value;
        _transfer(_from, _to, _value);
        return true;
    }

    /**
     * Set allowance for other address
     *
     * Allows `_spender` to spend no more than `_value` tokens on your behalf
     *
     * @param _spender The address authorized to spend
     * @param _value the max amount they can spend
     */
    function approve(address _spender, uint256 _value) public
        returns (bool success) {
        allowance[msg.sender][_spender] = _value;
        return true;
    }

    /**
     * Set allowance for other address and notify
     *
     * Allows `_spender` to spend no more than `_value` tokens on your behalf, and then ping the contract about it
     *
     * @param _spender The address authorized to spend
     * @param _value the max amount they can spend
     * @param _extraData some extra information to send to the approved contract
     */
    function approveAndCall(address _spender, uint256 _value, bytes _extraData)
        public
        returns (bool success) {
        tokenRecipient spender = tokenRecipient(_spender);
        if (approve(_spender, _value)) {
            spender.receiveApproval(msg.sender, _value, this, _extraData);
            return true;
        }
    }

    /**
     * Destroy tokens
     *
     * Remove `_value` tokens from the system irreversibly
     *
     * @param _value the amount of money to burn
     */
    function burn(uint256 _value) public returns (bool success) {
        require(balanceOf[msg.sender] >= _value);   // Check if the sender has enough
        balanceOf[msg.sender] -= _value;            // Subtract from the sender
        totalSupply -= _value;                      // Updates totalSupply
        Burn(msg.sender, _value);
        return true;
    }

    /**
     * Destroy tokens from other account
     *
     * Remove `_value` tokens from the system irreversibly on behalf of `_from`.
     *
     * @param _from the address of the sender
     * @param _value the amount of money to burn
     */
    function burnFrom(address _from, uint256 _value) public returns (bool success) {
        require(balanceOf[_from] >= _value);                // Check if the targeted balance is enough
        require(_value <= allowance[_from][msg.sender]);    // Check allowance
        balanceOf[_from] -= _value;                         // Subtract from the targeted balance
        allowance[_from][msg.sender] -= _value;             // Subtract from the sender's allowance
        totalSupply -= _value;                              // Update totalSupply
        Burn(_from, _value);
        return true;
    }
}

コントラクトの作成

左上の+ボタンを押して新たにコントラクトを作成します。
先ほどのコードを貼り付けます。

コントラクトで「TokenERC20」を選択し、
initialSupply,tokenName,tokenSymbol を入力します。
今回はOreOreCoinを10000 OC発行します。

createを実行します。
(マイニング開始、アカウントのアンロックを忘れずに)

miner.start()

personal.unlockAccount(eth.accounts[0],"pass1")

成功すると下記のように表示されます。

totalSupply,symbol,name,decimalsを押してみると先ほど発行した情報が表示されます。
Supplyの単位はweiなので注意
1 wei = 0.000 000 000 000 000 001 Ether

balanceOfでは残高を表示することが出来ます。
トークンを発行したアドレスを入力すると(ダブルクォーテーション""を忘れずに)
アカウントの残高を得ることが出来ます。

トークンの送金

実際にトークンをアカウント1から2へ送金してみます。
transferに "送付先アドレス"、送金量 を入力し、transferを実行します。

成功すればログが表示され、Detailsを押すと詳細が確認出来ます。

balanceOfで残高を確認し、アドレス1からアドレス2に100 OC送金されたことが分かります。

おわりに

簡単な独自トークンは割と簡単に作ることが分かりました。
独自トークンのデザインが大切そうですね。

参考にさせて頂きました。

Create your own CRYPTO-CURRENCY with Ethereum
Ethereumで仮想通貨を発行する