一括！！Windowsプリンタインストールバッチ

7829 ワード
bat driver Windows install Printer Windows テキストリンク

バッチファイル一発でプリンタのインストールする

自分用のメモです。
小さな会社とかで複数PCにインストールする時に使ってます。

対応環境

  • WindowsXP ～ Windows10
  • 32 or 64bit

手順

1.プリンタドライバを準備
2.必要な情報を探す
3.バッチファイルを作る！

1.プリンタドライバを準備

1.プリンタドライバをメーカーサイトからダウンロードします。
2.ダウンロードしたファイルを一式適当な場所に格納します。

2.必要な情報を探す

1.ファイルの中から.infファイルを探します。


※リコーだとこんなやつ

2.ファイルを開いてプリンタ名を探す


※リコーだとこんなやつで、これの「RICOH MP C4504 JPN RPCS」とかいうのがプリンタ名
この場合は５種類のプリンタに対応してるっぽい？

3.バッチファイルを作る！

1.バッチファイルに情報を当てはめて準備完了

※32bit版と64bit版が別ドライバなら、各々のファイルを用意する。

「call :setup～」の行をプリンタの数だけ並べればエンター１発で全部使えるようになる！はず。。。。

printer_install.bat
@echo off

call :checkWinVer
call :setup <プリンタに割り当てたIPアドレス> "<Windowsに設定するプリンタ名>" "<みつけたプリンタ名前>" "<32bitのINFファイルパス>" "<64bitのINFファイルパス>"
exit

:checkWinVer
VER | find "XP" > nul
IF not errorlevel 1 SET WIN_VER="Windows XP"
VER | find "Version 5.2." > nul
IF not errorlevel 1 SET WIN_VER="Windows XP"
VER | find "Version 6.0." > nul
IF not errorlevel 1 SET WIN_VER="Windows 2008"
VER | find "Version 6.1." > nul
IF not errorlevel 1 SET WIN_VER="Windows 7"
VER | find "Version 6.2." > nul
IF not errorlevel 1 SET WIN_VER="Windows 8"
VER | find "Version 10.0." > nul
IF not errorlevel 1 SET WIN_VER="Windows 10"
exit /b

:setup
REM #######  設定  #######
set PRT_IP=%1
set PRT_NAME=%2
set PRT_DV_NAME=%3
set PRT_DV_PATH_32=%4
set PRT_DV_PATH_64=%5
REM #######  処理  #######

IF EXIST %SYSTEMROOT%\System32\prnport.vbs (
set PRNPORT=%SYSTEMROOT%\System32\prnport.vbs
)
IF EXIST %SYSTEMROOT%\System32\Printing_Admin_Scripts\ja-JP\prnport.vbs (
set PRNPORT=%SYSTEMROOT%\System32\Printing_Admin_Scripts\ja-JP\prnport.vbs
)

if "%PROCESSOR_ARCHITECTURE%" EQU "x86" SET PRT_DV_PATH=%PRT_DV_PATH_32%
if "%PROCESSOR_ARCHITECTURE%" NEQ "x86" SET PRT_DV_PATH=%PRT_DV_PATH_64%
cd %SYSTEMROOT%\System32\Printing_Admin_Scripts\ja-JP
cscript %PRNPORT% -a -r IP_%PRT_IP% -h %PRT_IP% -o raw -n 9100
rundll32.exe printui.dll,PrintUIEntry /if /u /f %PRT_DV_PATH% /v %WIN_VER% /m %PRT_DV_NAME% /r IP_%PRT_IP% /b %PRT_NAME%
exit /b

変なところないかな。。。。。。