TeraTermで踏み台サーバ経由の多段SSHを自動化する

TTLマクロ_踏み台経由
│  connectinfo.dat                      パスワードファイル(自動生成)
│  springboard.ttl                      踏み台情報
│
├─WEBサーバ
│  │  config.ttl                        設定ファイル
│  │  connect.ttl                       接続コマンド情報
│  │  hosts.ttl                         サーバ情報
│  │
│  ├─開発環境
│  │      ホスト名(例：web-dev-a).ttl    サーバ接続用TTL
│  │      ホスト名(例：web-dev-b).ttl
│  │
│  └─本番環境
│          ホスト名(例：web-honban-a).ttl
│          ホスト名(例：web-honban-b).ttl
│
└─バッチサーバ
    │  config.ttl
    │  connect.ttl
    │  hosts.ttl
    │
    └─開発環境
            ホスト名(例：bat-dev-a).ttl
            ホスト名(例：bat-dev-b).ttl
・・・

;;踏み台情報
; 踏み台サーバのIPアドレス
FUMIDAI       = 'XXX.XXX.XXX.XXX'

;ユーザ、パスワード
LOGIN_USER='XXXXXX'                   ; 踏み台へのログインユーザ
PASS_FILE ='../../connectinfo.dat'

;ウインドウタイトル
PLACE='XXX環境'

COMMON_ID='XXXXXX'                     ; ログイン先の共通ログインID
COMMON_PASS='XXXXXX'                   ; ログイン先の共通ログインIDのパスワード

;INIファイルの読み込み有無  無:0 有:1
READ_INI=0

getdir CURDIR                          ; マクロの場所

;マクロファイルのベース名を作る
strsplit param1 '.'
SERVER_NAME = groupmatchstr1           ; マクロファイル名から接続先サーバ名を作る

SERVER_IP='*'

for i 0 ELEMENT_NO-1                   ; サーバ名からIPを得る
    strcompare SERVER_NAME HOSTEN[i]
    if  result=0  then
        SERVER_IP = HOSTIP[i]
        SERVER_COLOR = COLOR[i]
        break
    endif
next


strcompare SERVER_IP '*'
if result=0 then
    messagebox 'ホストが見つかりません' "エラーメッセージ"
    end
endif

;============================================== 
;; 接続先ホスト／ユーザ名／パスワード設定 
;LOGIN_USER = 'ユーザ名' 
;; パスワードファイル指定
;LOGIN_PASS = 'パスワード' 
;============================================== 
;; パスワード取得
getpassword PASS_FILE LOGIN_USER LOGIN_PASS

;; コマンド組立て 

COMMAND = FUMIDAI 
strconcat COMMAND ':22 /ssh /2 /auth=password /user=' 
strconcat COMMAND LOGIN_USER 
strconcat COMMAND ' /passwd=' 
strconcat COMMAND LOGIN_PASS

;; 接続 
connect COMMAND

sprintf2 TITLE '%s(%s:%s)' PLACE SERVER_NAME SERVER_IP

settitle TITLE

sprintf2 SSH_LOGIN 'ssh -o StrictHostKeyChecking=no %s@%s' COMMON_ID SERVER_IP
sprintf2 SSH_SERVER_COLOR "echo -ne '%s'" SERVER_COLOR

wait '$'
sendln SSH_LOGIN

wait 'password:'
sendln COMMON_PASS

wait '~]$'
sendln SSH_SERVER_COLOR
end

;   ホスト名、IPアドレスの2つの配列を定義する。
;   strdimで宣言する要素数は2つとも同じにする。
;   各配列の順番は、関連している。
;   増減した時は、ELEMENT_NOの変更と、各配列の要素を調整する。

ELEMENT_NO=2

;接続先ホスト名選択
strdim HOSTEN ELEMENT_NO

;ホスト名(例：web-dev-a、web-dev-b)
HOSTEN[0] = 'web-dev-a'
HOSTEN[1] = 'web-dev-b'

strdim HOSTIP ELEMENT_NO
;IPアドレス
HOSTIP[0] = 'XXX.XXX.XXX.XXX'
HOSTIP[1] = 'XXX.XXX.XXX.XXX'

strdim COLOR ELEMENT_NO
COLOR[0] = '\e]10;#ffffff\a\e]11;#303000\a'      ---文字色：#ffffff(白)、背景色：#303000(黄)
COLOR[1] = '\e]10;#ffffff\a\e]11;#303000\a'

include '../hosts.ttl'
include '../../springboard.ttl'
include '../config.ttl'
include '../connect.ttl'