unity 3 dストロークshader

unity 3 dゲームを始めたばかりの頃、線の問題に悩まされたことがある.この問題はマルチパスと深さテストを理解する必要がある.
最初のpassは単色でレンダリングされ、頂点を法線方向に拡張します.2番目のpassでは頂点が拡張されず、深さテストに合格できないため、深さを書くことはできません.2番目のパスは勝手に描けばいいので、深さに注意して書きます.レンダリング順序の問題に注意してください.ここでの順序はTransparentで、ソリッドモデルが描かれてから描きます.二重passはまだdrawcallが2回あることに注意して、しかも半透明の材質は正確な線を実現することができなくて、半透明の線は処理しにくくて、最も簡単なのは美術が直接辺をマップの上で描きますが、とても柔軟ではありませんが、私は知らないで、しかも何かもっと良い方法があるとは思いませんので、模型はできるだけ半透明の材質を少なくします.
この方法は実際には、モデルをコピーして法線を反転させる手法と似ていますが、この方法は優位で、まず資源量が減少し、骨格を必要とせず、2番目のモデルの骨格変換とmeshskinの消費を節約します.
次はshaderコードです.コードは海外のサイトから外しました.

Shader "Outline" {
	Properties {
		_Color ("Main Color", Color) = (.5,.5,.5,1)
		_OutlineColor ("Outline Color", Color) = (0,0,0,1)
		_Outline ("Outline width", Range (0.0, 0.03)) = .005
		_MainTex ("Base (RGB)", 2D) = "white" { }
	}
	CGINCLUDE
		#include "UnityCG.cginc"
		struct appdata {
			float4 vertex : POSITION;
			float3 normal : NORMAL;
		};
		struct v2f {
			float4 pos : POSITION;
			float4 color : COLOR;
		};
		uniform float _Outline;
		uniform float4 _OutlineColor;
		v2f vert(appdata v) {
			v2f o;
			o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
			float3 norm   = mul ((float3x3)UNITY_MATRIX_IT_MV, v.normal);
			float2 offset = TransformViewToProjection(norm.xy);
			o.pos.xy += offset * o.pos.z * _Outline;
			o.color = _OutlineColor;
			return o;
		}
	ENDCG
	SubShader {
		Tags { "Queue" = "Transparent" }
		Pass {
			Tags { "LightMode" = "Always" }
			Cull Off
			ZWrite Off
			//ZTest Always// ， 
			//ColorMask RGB // alpha not used
			Blend SrcAlpha OneMinusSrcAlpha // Normal

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			half4 frag(v2f i) :COLOR {
				return i.color;
			}
			ENDCG
		}
		Pass {
			Name "BASE"
			ZWrite On
			ZTest LEqual
			Blend SrcAlpha OneMinusSrcAlpha
			Material {
				Diffuse [_Color]
				Ambient [_Color]
			}
			Lighting On
			SetTexture [_MainTex] {
				ConstantColor [_Color]
				Combine texture * constant
			}
			SetTexture [_MainTex] {
				Combine previous * primary DOUBLE
			}
		}
	}
	Fallback "Diffuse"
}

//ZTest Alwaysという行のコードが開くと、効果的です.