Firefox 設定カスタマイズ

Set nwk = WScript.CreateObject("WScript.Network")
Set fso = CreateObject("Scripting.FileSystemObject")

tmpUserName = nwk.UserName

Dim strComputer
Dim Wmi
Dim colTarget
Dim strWork
Dim objRow
Dim aData

strComputer = "."
Set Wmi = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colTarget = Wmi.ExecQuery( "select Version from Win32_OperatingSystem" )
For Each objRow in colTarget
  strWork = objRow.Version
Next
aData = Split( strWork, "." )
strWork = aData(0) & "." & aData(1)

if CDbl( strWork ) = 5.1 then
  'WinXP
  tmp = "C:\Documents and Settings\" & tmpUserName & "\Application Data\Mozilla\Firefox\Profiles"
else
  'Win7
  tmp = "C:\Users\" & tmpUserName & "\AppData\Roaming\Mozilla\Firefox\Profiles"
end if

If fso.FolderExists(tmp) Then
  Set src = fso.GetFolder(tmp) ' 対象フォルダの指定
  '指定のフォルダに格納された各サブフォルダを処理する
  tmpfolder = ""
  For Each FolderName In src.Subfolders
    tmpfolder = FolderName
    If fso.FolderExists(tmpfolder) Then
      Set oLog = FSO.CreateTextFile(tmpfolder & "\user.js")
      '起動時に開くページをホームページにする
      oLog.WriteLine("user_pref('browser.startup.page', 1);")
      '起動時のホームページ
      oLog.WriteLine("user_pref('browser.startup.homepage','http://www.yahoo.co.jp');")         
      '新規タブ起動時のホームページ
      oLog.WriteLine("user_pref('browser.newtab.url', 'http://www.yahoo.co.jp');")
      'ページ先読みを無効
      oLog.WriteLine("user_pref('network.prefetch-next',false);")
      'バックグラウンドでタブ読み込み無効
      oLog.WriteLine("user_pref('browser.tabs.loadDivertedInBackground', false);")
      'Webブラウザの既定設定画面表示無効
      oLog.WriteLine("user_pref('browser.shell.checkDefaultBrowser', false);")
      'アップデート確認無効
      oLog.WriteLine("user_pref('app.update.enabled', false);") 
      oLog.Close()
      Set oLog = Nothing
    End If
  Next
End If