ExternalProject_Add(<target name> [<option> ...])

# ExternalProject_Addを使えるようにするためのおまじない
include(ExternalProject)

# GoogleTestをビルドするディレクトリを指定
#（ここではビルドディレクトリ内のgtest）
set(GTEST_BUILD_DIR ${CMAKE_BINARY_DIR}/gtest)
# GoogleTestをインストールするディレクトリを指定
# （ここではプロジェクトルートディレクトリ内のgtest）
set(GTEST_INSTALL_DIR ${PROJECT_SOURCE_DIR}/gtest)
# GoogleTestのヘッダファイルがあるディレクトリ
set(GTEST_INCLUDE_DIR ${GTEST_INSTALL_DIR}/include)
# GoogleTestの静的ライブラリがあるフォルダ
set(GTEST_LIB_DIR ${GTEST_INSTALL_DIR}/lib)

# GoogleTestはpthreadが必要なのでCMakeに探してもらう
find_package(Threads REQUIRED)

# GoogleTestを外部プロジェクトとして追加
ExternalProject_Add(googletest
        # ダウンロードするURLを指定
        URL https://github.com/google/googletest/archive/release-1.8.0.tar.gz
        # GoogleTestをビルドするディレクトリを指定
        PREFIX ${GTEST_BUILD_DIR}
        # GoogleTestをダウンロードして解凍した後、cmakeを実行するときに渡される引数
        # この例の場合、自分で`cmake -DCMAKE_INSTALL_PREFIX=...`とするのと同じ
        # cmakeで元々定義されている変数（CMAKE_CXX_FLAGS）やライブラリで定義されている
        # 変数を使用可能。引数の頭に`-D`をつけて与えることを忘れずに！
        CMAKE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=${GTEST_INSTALL_DIR}
    )

# GoogleTestにgtestという名前をつけ、外部の（＝このプロジェクトでビルド方法を定義しない）
# 静的ライブラリとして登録
add_library(gtest IMPORTED STATIC GLOBAL)
# gtestに対応する静的ライブラリのファイルとその依存ライブラリpthreadを指定
set_target_properties(gtest PROPERTIES
    IMPORTED_LOCATION ${GTEST_LIB_DIR}/libgtest.a
    INTERFACE_LINK_LIBRARIES ${CMAKE_THREAD_LIBS_INIT}
)

# gtest_mainも必要な場合はadd_libraryからset_target_propertiesまでの
# gtestをgtest_mainに書き換えて追加する

add_executable(<target> <sources>)
target_link_libraries(<target> gtest)

set(GTEST_INSTALL_DIR ${CMAKE_SOURCE_DIR}/gtest CACHE PATH "GoogleTest install directory")

# Eigenのビルド・インストール・インクルードディレクトリを定義
set(EIGEN_BUILD_DIR   ${CMAKE_BINARY_DIR}/eigen)
set(EIGEN_INSTALL_DIR ${PROJECT_SOURCE_DIR}/eigen)
set(EIGEN_INCLUDE_DIR ${EIGEN_INSTALL_DIR}/include)

# Eigenを外部プロジェクトとして追加
ExternalProject_Add(
    eigen
    URL http://bitbucket.org/eigen/eigen/get/3.3.4.tar.gz
    PREFIX ${EIGEN_BUILD_DIR}
    # CMakeのconfigureは必要ないので空白（""）を与えることで何もさせない
    CONFIGURE_COMMAND ""
    # ビルドも不要
    BUILD_COMMAND ""
    # インストールも不要
    INSTALL_COMMAND ""
    # テストも不要
    TEST_COMMAND ""
    )

# Eigenをダウンロードして解凍してできるフォルダを得る
ExternalProject_Get_Property(eigen SOURCE_DIR)

# 上で得たフォルダ内の指定ディレクトリの中身を別のフォルダ内にコピーする
# この場合${SOURCE_DIR}/Eigen --> ${EIGEN_INCLUDE_DIR}/Eigenへとコピーされる
ExternalProject_Add_Step(
    # 対象の外部プロジェクト
    eigen
    # 実行する操作
    copySource
    # 対象ディレクトリ
    WORKING_DIRECTORY ${SOURCE_DIR}
    # コマンド
    COMMAND ${CMAKE_COMMAND} -E copy_directory Eigen ${EIGEN_INCLUDE_DIR}/Eigen
    COMMENT "Copying headers to ${EIGEN_INCLUDE_DIR}/Eigen"
    )

# あとはインクルードディレクトリとして登録するだけ
include_directories(SYSTEM ${EIGEN_INCLUDE_DIR})