;# ■概要
;# ・Cisco機器へSSH接続し、show run取得後にTeratermを閉じます。
;# 
;# ・ログ出力場所
;#       C:\teraterm\log
;# 
;# ・ログ名
;#       \HOSTNAME_YYYYMMDD_HHMMSS.log
;# 
;# ■接続情報の設定(環境に合わせて修正)
HOSTS_IP = '192.168.0.1'
HOSTNAME = 'hostname'
LOG_USER = 'login-user'
LOG_PASS = 'login-pass'
ENA_PASS = 'enable-pass'
SHOW_COM = 'show running-config'

;# ～～～～以下は修正不要です。～～～～
;# ■変数等の作成
;## ログ保存先指定
LOG_PATH = 'C:\teraterm'
LOG_FILE = LOG_PATH
strconcat LOG_FILE '\log'

;## ログファイル名の設定
getdate DATETIME '_%Y%m%d_%H%M%S_sh-run.log'
FULLPATH = LOG_FILE
strconcat FULLPATH '\'
strconcat FULLPATH HOSTNAME
strconcat FULLPATH DATETIME

;## プロンプトの作成
PP_CISCO = HOSTNAME
strconcat PP_CISCO '#'

;## SSH接続コマンド作成
COMMAND = HOSTS_IP
strconcat COMMAND ':22 /ssh /2 /auth=password /user='
strconcat COMMAND LOG_USER
strconcat COMMAND ' /passwd='
strconcat COMMAND LOG_PASS
;#↓設定ファイルを機器毎に分ける場合の設定ファイル指定（今回はOFF）
;strconcat COMMAND ' /F=C:\teraterm\ini\test.ini'
;#↓SSHでの初回接続確認をOFFにするオプション（今回はOFF）
;strconcat COMMAND ' /nosecuritywarning'


;# ■マクロの実行～終了
;## 「MACRO ダイアログ」ウィンドウを非表示 ※デバッグ時はOFFにする。
show -1

;## ログ保存先のフォルダが無ければ作成。
foldersearch LOG_FILE
if result = 0 then
    foldercreate LOG_FILE
    if result <> 0 then
        messagebox 'Folder Error'
        end
    endif
endif


;## SSH接続
connect COMMAND

;## キーボード入力抑制（誤操作防止）開始
enablekeyb 0

;## 接続判定(接続が出来たか確認）
if result <> 2 then
    messagebox 'Connection Error'
    end
endif


;## ログの取得開始
loginfo logfilename
if result <> -1 then
   logclose
   logopen FULLPATH 0 1
else
   logopen FULLPATH 0 1
endif
sendln ''

;## 「Tera Term: ログ」ウィンドウを非表示
showtt 6

;## enable, ter len 0
wait '>' 
sendln 'enable' 
wait 'Password:' 
sendln ENA_PASS

wait PP_CISCO
sendln ''
sendln 'terminal length 0'
mpause 200
sendln 'terminal exec prompt timestamp'
mpause 200


;## showコマンドの取得
sendln ''
wait PP_CISCO
mpause 200
sendln SHOW_COM
pause 3    ;#show tech等の長いコマンドはpauseを長くする
sendln ''
sendln ''

;# コマンド終了後にTeraTermを閉じる
sendln ''
wait PP_CISCO
mpause 500
sendln 'exit'
unlink