@echo off
rem 親フォルダ以下の各フォルダ内で、指定した拡張子のファイルをマージするバッチ
setlocal enabledelayedexpansion

rem ◆変数定義◆
set LOG_FILE=%CD%\log_file.txt
set CURRENT_DIR=%CD%
set S_DATE=%DATE%
set S_TIME=%TIME%
set IS_MERGED_DIR=FALSE

rem ■メイン■
echo "親フォルダ以下の各フォルダ内で、指定した拡張子のファイルをマージします。"
call :guidanceExtention
call :guidanceStart
call :cfmAndDelDir
call :merge
call :dirSearchAndMerge
goto :mergeEnd

rem ◆ガイダンス（拡張子）◆
:guidanceExtention
set /p RES1="マージ対象ファイルの拡張子を入力してください。...[拡張子を入力] "
exit /b

rem ◆ガイダンス（開始）◆
:guidanceStart
set /p RES2="マージを開始しますか？...[Y/N] " 
if /i %RES2%==Y exit /b
if /i %RES2%==YES exit /b
goto :END

rem ◆mergedディレクトリ存在確認◆
:cfmAndDelDir
for /r /d %%1 in (*) do (
    cd %%1
    if /i exist merged (
        echo 削除対象ディレクトリ：%%1\merged
        set IS_MERGED_DIR=True
    )
)
cd %CURRENT_DIR%
if /i %IS_MERGED_DIR%==True call :deleteDir
exit /b

rem ◆一括フォルダ削除◆
:deleteDir
set /p RES3="上記の出力先フォルダが既に存在します。削除してもよろしいですか？...[Y/N] "
if /i %RES3%==Y goto :delOK
if /i %RES3%==YES goto :delOK
goto :END
:delOK
for /r %%2 in (merged) do (
    rmdir /s /q "%%2" > nul 2>&1
)
echo 上記ディレクトリを削除しました。
exit /b

rem ◆実行ディレクトリ配下のディレクトリを調査◆
:dirSearchAndMerge
for /r /d %%3 in (*) do (
    cd %%3
    call :merge %%3
)
exit /b

rem ◆マージ処理◆
:merge
if exist *.%RES1% (
    rem merged.*が無ければ、ディレクトリ作成＆マージ処理
    if not exist merged.%RES1% (
        mkdir merged
        echo マージ作業ディレクトリ：%1
        copy /b *.%RES1% merged\merged.%RES1%
    )
)
exit /b

rem ◆終了処理◆
:mergeEnd
echo マージ処理が終了しました。プログラムを終了します。
echo 開始日時：%S_DATE% %S_TIME%
echo 終了日時：%DATE% %TIME%
pause

:end
exit