set -x CIRCLECI_API_TOKEN xxxx # トークンを設定
function circleci_latest_build -d "open circleci latest build page"
  set base_url "https://circleci.com/api/v1.1/project"
  set src_root (ghq root)
  set current_path (pwd)
  switch $current_path
  case "$src_root/*"
    set repository_path (string replace "$src_root/" "" $current_path)
    for el in (string split "/" $repository_path)
      set -a info $el
    end
    switch $info[1]
    case "github.com"
      set vcs_type "github"
    case "bitbucket.org"
      set vcs_type "bitbucket"
    case "*"
      echo "invalid vcs type: $info[1]"
      return 1
    end
    set branch_name (git symbolic-ref --short HEAD)
    if test -z $branch_name
      echo "failed to resolve branch name"
      return 1
    end
    set url "$base_url/$vcs_type/$info[2]/$info[3]/tree/$branch_name?circle-token=$CIRCLECI_API_TOKEN"
    set res (curl -sS -w "\n%{http_code}" $url)
    set code $res[-1]
    set body $res[1..-2]
    switch $code
    case "200"
      if test "$body" != "[ ]"
        echo $res[1..-2] | jq ".[0].build_url" | xargs open
      else
        echo "no build found"
      end
    case "*"
      echo "got status $code"
      echo $body | jq
    end
  case "*"
    echo "current path does not contain $src_root: $current_path"
    return 1
  end
end